Send Email but with a attachment

• 
• 

Details

Category: ABAP

Published on Tuesday, 21 April 2009 19:17

Written by Anon

Hits: 10760

If you wish to send an email with an attachment, I am sure this code will help you to take a start.
What I have done is triggered a program to send Customer List in form of attachment. You just need to enter the customer no and check the Customer list in your SAP MAIL BOX.

REPORT  ZPPTEST28_MYMAIL                               .
Tables: KNA1.
DATA : w_name(135).

SELECTION-SCREEN :
SKIP, BEGIN OF LINE,COMMENT 5(35) var1 FOR FIELD s_name.
SELECT-OPTIONS :
   s_name FOR w_name DEFAULT sy-uname NO INTERVALS.
SELECTION-SCREEN END OF LINE.

SELECTION-SCREEN :
SKIP, BEGIN OF LINE,COMMENT 5(35) var2 FOR FIELD s_culist.
SELECT-OPTIONS :
* How many Customer's List you wish to mail?
  s_culist FOR KNA1-KUNNR.
SELECTION-SCREEN END OF LINE.


INITIALIZATION.
  var1 = 'Recipient Address'.
  var2 = 'Customer No'.
  s_culist-low = '10'.
  s_culist-high = '50'.
  Append s_culist.

*---------------------------------------------------------------------*
START-OF-SELECTION.

  PERFORM f_send_mail.

*---------------------------------------------------------------------*
* Form f_send_mail
*---------------------------------------------------------------------*
FORM f_send_mail.
*Routine to send mail
* Data Declaration
  DATA:
    l_datum(10),
    ls_docdata    TYPE sodocchgi1,
    lt_objpack    TYPE TABLE OF sopcklsti1 WITH HEADER LINE,
    lt_objhead    TYPE TABLE OF solisti1   WITH HEADER LINE,
    lt_objtxt     TYPE TABLE OF solisti1   WITH HEADER LINE,
    lt_objbin     TYPE TABLE OF solisti1   WITH HEADER LINE,
    lt_reclist    TYPE TABLE OF somlreci1  WITH HEADER LINE,
    lt_listobject TYPE TABLE OF abaplist   WITH HEADER LINE,

    l_tab_lines TYPE i,
    l_att_type  LIKE soodk-objtp.

* START THE REPORT BY ENTERING CUSTOMER NOS
* AND DUMP TO ABAP MEMORY

  SUBMIT RFDKVZ00 WITH DD_KUNNR-LOW IN s_culist
                  WITH valid = 'X'
                  WITH notvalid = space
                  WITH unlocked = 'X'
                  WITH locked = space
             EXPORTING LIST TO MEMORY AND RETURN.

* Read list from memory into table
  CALL FUNCTION 'LIST_FROM_MEMORY'
    TABLES
      listobject = lt_listobject
    EXCEPTIONS
      not_found  = 1
      OTHERS     = 2.

  IF sy-subrc <> 0.
    MESSAGE ID '61' TYPE 'E' NUMBER '731'
       WITH 'LIST_FROM_MEMORY'.
  ENDIF.

* Because listobject is of size RAW(1000)
  CALL FUNCTION 'TABLE_COMPRESS'
    TABLES
      in             = lt_listobject
      out            = lt_objbin
    EXCEPTIONS
      compress_error = 1
      OTHERS         = 2.

  IF sy-subrc <> 0.
*   Error in function module &1
    MESSAGE ID '61' TYPE 'E' NUMBER '731'
       WITH 'TABLE_COMPRESS'.
  ENDIF.

* NOTE: Creation of attachment is finished yet.
* For your report, the attachment should be placed into table
* objtxt for plain text or
* objbin for binary content.
* Now create the message and send the document.
* Create Message Body
* Title and Description
  ls_docdata-obj_name = 'Customer List'.
  CONCATENATE 'List of Customers selected upto -' s_culist-high
        INTO ls_docdata-obj_descr SEPARATED BY space.

* Main Text
  lt_objtxt = 'List of Customers'.

  APPEND lt_objtxt.
* Write Packing List (Main)
  DESCRIBE TABLE lt_objtxt LINES l_tab_lines.
  READ TABLE lt_objtxt INDEX l_tab_lines.
  ls_docdata-doc_size = ( l_tab_lines - 1 ) * 255 + STRLEN( lt_objtxt ).
  CLEAR lt_objpack-transf_bin.
  lt_objpack-head_start = 1.
  lt_objpack-head_num = 0.
  lt_objpack-body_start = 1.
  lt_objpack-body_num = l_tab_lines.
  lt_objpack-doc_type = 'RAW'.
  APPEND lt_objpack.

* Create Message Attachment
* Write Packing List (Attachment)
  l_att_type = 'ALI'.
  DESCRIBE TABLE lt_objbin LINES l_tab_lines.
  READ TABLE lt_objbin INDEX l_tab_lines.
  lt_objpack-doc_size = ( l_tab_lines - 1 ) * 255 + STRLEN( lt_objbin ).
  lt_objpack-transf_bin = 'X'.
  lt_objpack-head_start = 1.
  lt_objpack-head_num = 0.
  lt_objpack-body_start = 1.
  lt_objpack-body_num = l_tab_lines.
  lt_objpack-doc_type = l_att_type.
  lt_objpack-obj_name = 'ATTACHMENT'.
  lt_objpack-obj_descr = 'List_of_Users'.                   "#EC *
  APPEND lt_objpack.

* Create receiver list
  LOOP AT s_name.
    lt_reclist-receiver = s_name-low.
    lt_reclist-rec_type = 'B'.
    APPEND lt_reclist.
  ENDLOOP.

* Send Message
  CALL FUNCTION 'SO_NEW_DOCUMENT_ATT_SEND_API1'
    EXPORTING
      document_data              = ls_docdata
      put_in_outbox              = ''
    TABLES
      packing_list               = lt_objpack
      object_header              = lt_objhead
      contents_bin               = lt_objbin
      contents_txt               = lt_objtxt
      receivers                  = lt_reclist
    EXCEPTIONS
      too_many_receivers         = 1
      document_not_sent          = 2
      document_type_not_exist    = 3
      operation_no_authorization = 4
      parameter_error            = 5
      x_error                    = 6
      enqueue_error              = 7
      OTHERS                     = 8.

  IF sy-subrc = 0.
*   Document sent
    MESSAGE ID 'SO' TYPE 'S' NUMBER '022'.
  ELSE.
*   Document <&> could not be sent
    MESSAGE ID 'SO' TYPE 'S' NUMBER '023'
       WITH ls_docdata-obj_name.
  ENDIF.

ENDFORM.                               " F_SEND_MAIL

• < Prev
• Next >